settings.gradle

pluginManagement {
    repositories {
        google()
        exclusiveContent {
            forRepository {
                maven {
                    url = uri("https://a8c-libs.s3.amazonaws.com/android")
                }
            }
            filter {
                includeGroup "com.automattic.android"
                includeGroup "com.automattic.android.measure-builds"
            }
        }
        gradlePluginPortal()
    }
}

plugins {
    id 'com.gradle.develocity' version '3.19'
}

gradle.ext.isCi = System.getenv('CI')?.toBoolean() ?: false

dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        mavenCentral()
        google()
        maven {
            url 'https://a8c-libs.s3.amazonaws.com/android'
            content {
                includeGroup "org.wordpress"
                includeGroup "org.wordpress.fluxc"
                includeGroup "org.wordpress.fluxc.plugins"
                includeGroup "org.wordpress.wellsql"
                includeGroup "org.wordpress.mediapicker"
                includeGroup "com.automattic"
                includeGroup "com.automattic.tracks"
                includeGroup "com.gravatar"
                includeGroup "org.wordpress.aztec"
            }
        }
        maven {
            url 'https://zendesk.jfrog.io/zendesk/repo'
            content {
                includeGroup "com.zendesk"
                includeGroup "com.zendesk.belvedere2"
            }
        }
        maven {
            url "https://a8c-libs.s3.amazonaws.com/android/jcenter-mirror"
            content {
                includeVersion "com.android.volley", "volley", "1.1.1"
                includeVersion "com.google.android", "flexbox", "2.0.1"
                includeVersion "com.jraska", "falcon", "2.1.1"
                includeVersion "org.wordpress", "wellsql", "1.6.0"
                includeVersion "org.wordpress", "wellsql-core", "1.6.0"
            }
        }
        maven {
            url "https://jitpack.io"
            content {
                includeModule("com.github.wordpress-mobile.WordPress-Aztec-Android", "aztec")
                includeModule("com.github.wordpress-mobile.WordPress-Aztec-Android", "glide-loader")
                includeModule("com.github.chrisbanes", "PhotoView")
                includeModule("com.github.PhilJay", "MPAndroidChart")
            }
        }
    }
}


rootProject.name = 'WCAndroid'

include ':libs:commons'
include ':libs:cardreader'
include ':libs:apifaker'
include ':WooCommerce'

gradle.ext.fluxCBinaryPath = "org.wordpress:fluxc"
gradle.ext.fluxCWooCommercePluginBinaryPath = "org.wordpress.fluxc.plugins:woocommerce"
gradle.ext.loginFlowBinaryPath = "org.wordpress:login"
gradle.ext.mediaPickerBinaryPath = "org.wordpress:mediapicker"
gradle.ext.mediaPickerDomainBinaryPath = "org.wordpress.mediapicker:domain"
gradle.ext.mediaPickerSourceCameraBinaryPath = "org.wordpress.mediapicker:source-camera"
gradle.ext.mediaPickerSourceDeviceBinaryPath = "org.wordpress.mediapicker:source-device"
gradle.ext.mediaPickerSourceGifBinaryPath = "org.wordpress.mediapicker:source-gif"
gradle.ext.mediaPickerSourceWordPressBinaryPath = "org.wordpress.mediapicker:source-wordpress"

gradle.ext {
    compileSdkVersion = 35
    targetSdkVersion = 34
    minSdkVersion = 26
}

apply from: './config/gradle/include_builds.gradle'
apply from: './config/gradle/gradle_build_cache.gradle'
apply from: './config/gradle/gradle_build_scan.gradle'
include ':WooCommerce-Wear'