Add the vagrant-prompt plugin to the PROMPT

[alexventuraio]

I recently installed Oh My ZSH! and then I configured the Powerlevel10k theme following the official instruction.

Then, based on the list of supported official plugins here I wanted to use the vagrant-prompt one and my .zshrc file now has.

plugins=(... vagrant-prompt)

But following the described instructions from the plugin, I'm not sure where exactly to add the vagrant_prompt_info function.

I have tried adding it to here:

typeset -g POWERLEVEL9K_LEFT_PROMPT_ELEMENTS=(
  # =========================[ Line #1 ]=========================
  os_icon                 # os identifier
  dir                     # current directory
  vcs                     # git status
  vagrant_prompt_info
  # =========================[ Line #2 ]=========================
  newline                 # \n
  # prompt_char           # prompt symbol
)

Also in this other one like this:

typeset -g POWERLEVEL9K_RIGHT_PROMPT_ELEMENTS=(
  # =========================[ Line #1 ]=========================
  status                  # exit code of the last command
  command_execution_time  # duration of the last command
  ..
  vagrant_status
  # =========================[ Line #2 ]=========================
  newline
)

function vagrant_status() {
  p10k segment -b 1 -f 3 -t '$(vagrant_prompt_info)'
}

But I still get nothing.

If I exec the vagrant_prompt_info function it shows this:

$ vagrant_prompt_info
%{%}[%{%}●%{%}]%{%} %

Does anyone have an idea of what I maybe doing wrong?

[romkatv]

You would need to implement a custom prompt segment. Run p10k help segment for docs.

[alexventuraio]

Hmm, I thought that's what vagrant-prompt plugin was made for.
But maybe it is useless (or not compatible) for the Powerleve10K theme, right?

[romkatv]

Hmm, I thought that's what vagrant-prompt plugin was made for.

That's right.

But maybe it is useless (or not compatible) for the Powerleve10K theme, right?

It works with Powerlevel10k. Do see my previous comment!

[alexventuraio]

I think that the output from the vagrant-prompt plugin is meant for other type of prompt that do not place nicely with Powerleve10K theme.

So, adding that plugin to your plugins=(... vagrant vagrant-prompt) is useless and you better remove it.

Based on the vagrant_prompt_info function provided by the plugin mentioned, I had to rewrite it to place nicely with the pk10 segment command from Powerlevel10K theme:

function prompt_vagrant_status() {
  if [[ ! -d .vagrant || ! -f Vagrantfile ]]; then
    return
  fi

  local vm_states vm_state
  vm_states=(${(f)"$(vagrant status 2> /dev/null | sed -nE 's/^[^ ]* *([[:alnum:] ]*) \([[:alnum:]_]+\)$/\1/p')"})

  for vm_state in $vm_states; do
    case "$vm_state" in
      running) p10k segment -b 239 -f green -i '●' ;;
      "not running"|poweroff) p10k segment -b 239 -f red -i '●' ;;
      paused|saved|suspended) p10k segment -b 239 -f cyan -i '●' ;;
      "not created") p10k segment -b 239 -f white -i '○' ;;
    esac
  done
}

[romkatv]

I haven't tried it, but I expect vagrant_prompt_info to work if used like this:

function prompt_my_vagrant() {
  p10k segment -t "$(vagrant_prompt_info)"
}

POWERLEVEL9K_MY_VAGRANT_SHOW_ON_UPGLOB='.vagrant|Vagrantfile'

Does it work for you?

[alexventuraio]

Oh I think it didn't work before because I had to put these env variables in my .zshrc file:

ZSH_THEME_VAGRANT_PROMPT_RUNNING="%{$fg_no_bold[green]%}●"
ZSH_THEME_VAGRANT_PROMPT_POWEROFF="%{$fg_no_bold[red]%}●"
ZSH_THEME_VAGRANT_PROMPT_SUSPENDED="%{$fg_no_bold[yellow]%}●"
ZSH_THEME_VAGRANT_PROMPT_NOT_CREATED="%{$fg_no_bold[white]%}○"

After adding them, it works as well